# ==========================================================================
# This ebuild come from voip repository. Zugaina.org only host a copy.
# For more info go to http://gentoo.zugaina.org/
# ************************ General Portage Overlay ************************
# ==========================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/linphone-2.0.1-r1.ebuild,v 1.5 2008/01/22 04:44:42 vapier Exp $

# Note: video support in linphone relies on swscaler being disabled
#       in ffmpeg.  this is because the video code in linphone is old
#       and uses the old interface.  solution: fix linphone's video
#       code.  workaround: build ffmpeg w/out --enable-swscaler.

inherit eutils

DESCRIPTION="Voice Over IP phone (internet phone which uses SIP)"
HOMEPAGE="http://www.linphone.org/"
SRC_URI="http://download.savannah.nongnu.org/releases/${PN}/unstable/source/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa arts console doc gtk ilbc ipv6 portaudio video xv"
# XXX: Should "video" be split into ffmpeg/libsdl ?  They are two distinct
#      things: libsdl is just for video display while ffmpeg is just for
#      video capture ... but does anyone actually want a one-way linphone ?

RDEPEND="dev-libs/glib
	doc? ( app-doc/doxygen )
	dev-perl/XML-Parser
	net-dns/bind-tools
	>=net-libs/libosip-3.0.3
	>=net-libs/libeXosip-3.0.3
	portaudio? ( >=media-libs/portaudio-19_pre )
	>=media-libs/speex-1.2_beta3
	media-sound/gsm
	x86? ( xv? ( dev-lang/nasm ) )
	gtk? (
		>=x11-libs/gtk+-2
		gnome-base/libglade
	)
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/arts )
	ilbc? ( dev-libs/ilbc-rfc3951 )
	video? (
		media-libs/libsdl
		media-video/ffmpeg
		>=media-libs/libtheora-1.0_alpha7
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"
# use the bundled ortp until newer versions enter portage
#	>=net-libs/ortp-0.13.1-r1

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/linphone-pkg_config.diff

	#( cd mediastreamer2 && eautoconf ) || die "eautoconf failed"
	#for DIR in . mediastreamer2 oRTP; do
	#	( cd "$DIR" && libtoolize --force ) || die "libtoolize in $DIR failed"
	#done
	./autogen.sh || die "autogen failed"
}
src_compile() {
	use doc || export ac_cv_path_DOXYGEN=false
	econf \
		--disable-strict \
		--libdir=/usr/$(get_libdir)/linphone \
		--libexecdir=/usr/$(get_libdir)/linphone/exec \
		$(use_enable console console_ui) \
		$(use_enable doc manual) \
		$(use_enable gtk gtk_ui) \
		$(use_with ilbc) \
		$(use_enable ipv6) \
		$(use_enable alsa) \
		$(use_enable arts artsc) \
		$(use_enable video) \
		$(use_enable portaudio) \
		$(use_enable x86 truespeech) \
		|| die "Unable to configure"
		#--enable-external-ortp
	emake || die "Unable to make"
}

src_install () {
	emake DESTDIR="${D}" install || die "Failed to install"
	dodoc AUTHORS BUGS ChangeLog INSTALL NEWS README README.arm TODO

	# don't install mediastreamer/ortp includes, docs and pkgconfig files
	# to avoid conflicts with net-libs/ortp
	rm -r "${D}"/usr/include/{mediastreamer2,ortp} || die
	rm -r "${D}"/usr/$(get_libdir)/linphone/pkgconfig/{mediastreamer,ortp}.pc || die
	use doc && ( rm -r "${D}"/usr/share/doc/ortp || die )
	mv "${D}"/usr/$(get_libdir)/{linphone/,}pkgconfig || die
}